asp로 RSS 구현하기

<?xml version="1.0" encoding="EUC-KR" ?>

<%
Response.ContentType = "text/xml"
Set xmlPars = Server.CreateObject("Msxml2.DOMDocument")

' 여기서 부터 rss 정보를 담는다.
Set rss = xmlPars.CreateElement("rss")
rss.setAttribute "version", "2.0"
rss.setAttribute "xmlns:dc", "http://purl.org/dc/elements/1.1/"
rss.setAttribute "xmlns:sy", "http://purl.org/rss/1.0/modules/syndication/"
rss.setAttribute "xmlns:admin", "http://webns.net/mvcb/"
rss.setAttribute "xmlns:rdf", "http://www.w3.org/1999/02/22-rdf-syntax-ns#"
xmlPars.AppendChild(rss)

'<channel> 시작

Set Channel = xmlPars.CreateElement("channel")
rss.AppendChild(Channel)

'<title>정보
Set title = xmlPars.CreateElement("title")
Channel.AppendChild(title)
Channel.childnodes(0).text = "개인브랜드_포트폴리오"

'<link>정보
Set channel_link = xmlPars.CreateElement("link")
Channel.AppendChild(channel_link)
Channel.childnodes(1).text = "http://www.portfolio.co.kr"

'<description>정보
Set description = xmlPars.CreateElement("description")
Channel.AppendChild(description)
Channel.childnodes(2).text = "Trust YourSelf!!"

'<dc:language>정보
Set language = xmlPars.CreateElement("dc:language")
Channel.AppendChild(language)
Channel.childnodes(3).text = "ko"

'<image>정보
''Set image = xmlPars.CreateElement("image")
''Channel.AppendChild(image)

'이미지 정보에 들어갈 것들
''set i_title = xmlPars.CreateElement("title")
''set i_url = xmlPars.CreateElement("url")
''set i_width = xmlPars.CreateElement("width")
''set i_height = xmlPars.CreateElement("height")

''image.AppendChild(i_title)
''image.AppendChild(i_url)
''image.AppendChild(i_width)
''image.AppendChild(i_height)

''image.childnodes(0).text = "이미지 제목"
''image.childnodes(1).text = "이미지 경로"
''image.childnodes(2).text = "이미지 가로 사이즈"
''image.childnodes(3).text = "이미지 세로 사이즈"

' 여기서 부터는 포스트에 대해서 출력

' 우선 데이터를 읽어오자
objconn = "Provider=SQLOLEDB; Data Source=.; Initial Catalog=NPortfolio; User ID=PortfolioHegeJS; Password=k015106army;"

SQL = "select top 100 subject, portUrl, postRdate, ppidx, substring(content,1,30) from productPost where subject <> '' and outChk <> '1' order by ppidx desc"
set rs = Server.CreateObject("ADODB.Recordset")
rs.Open SQL,objconn,3

' 여기서 부터 루프를 돌리자.
Do until rs.EOF

'<item> 이라는 노드를 추가
Set item = xmlPars.CreateElement("item")
Channel.AppendChild(item)

  ' 여기서부터 해당 포스트의 세부 정보를 출력
  set title = xmlPars.CreateElement("title") '
  set link = xmlPars.CreateElement("link")
  set description =  xmlPars.CreateElement("description")
  set dcdate =  xmlPars.CreateElement("dc:date")
  set dcsubject =  xmlPars.CreateElement("dc:subject")

  item.AppendChild(title)
  item.AppendChild(link)
  item.AppendChild(description)
  item.AppendChild(dcdate)
  item.AppendChild(dcsubject)

  item.childnodes(0).text = rs(0)
  item.childnodes(1).text = "http://www.portfolio.co.kr/" & rs(1) & "/" & rs(3)
  item.childnodes(2).text = rs(4)
  item.childnodes(3).text = rs(2)
  item.childnodes(4).text = rs(3)

rs.movenext
loop

' 마지막으로 최종적으로 뿌려주자.
Response.Write xmlPars.xml

'마무리 ^^;

rs.close

set rs = nothing

Set xmlPars = nothing
%>

	검색어를 입력하십시오. 검색양식 제출
	Web islet4you.tistory.com